Die Mathe-Redaktion - 24.11.2017 10:25 - Registrieren/Login
Auswahl
Schwarzes Brett
Aktion im Forum
Suche
Stichwortsuche in Artikeln und Links von Matheplanet
Suchen im Forum
Suchtipps

Bücher
Englische Bücher
Software
Suchbegriffe:
Mathematik bei amazon
Naturwissenschaft & Technik
In Partnerschaft mit Amazon.de
Kontakt
Mail an Matroid
[Keine Übungsaufgaben!]
Impressum

Bitte beachten Sie unsere Nutzungsbedingungen, die Distanzierung, unsere Datenschutzerklärung und
die Forumregeln.

Sie können Mitglied werden oder den Newsletter bestellen.

Der Newsletter Okt. 2017

Für Mitglieder
Mathematisch für Anfänger
Wer ist Online
Aktuell sind 801 Gäste und 16 Mitglieder online.

Sie können Mitglied werden:
Klick hier.

Über Matheplanet
 
Bearbeiten von: Abschnitt [Änderungshistorie]
  Zeilenumbrüche automatisch mache ich selbst mit HTML    

Ich möchte eine Mail an , nachdem mein Vorschlag bearbeitet ist.
  Nachricht zur Änderung:

Eingabehilfen (JavaScript): [Link extern intern] [$$] [MathML?]
[fed-Bereich] [LaTeX-inline] [LaTeX-display] [hide-Bereich] [Quelltext [num.]][?]
[Link zurück zum Artikelabschnitt]

Vorschau:
Einige Übertragungselemente


Einige Übertragungselemente


Am besten sieht man die Eigenschaften der Bodediagramme an einigen Beispielen. Die Übertragungsglieder werden mit Abkürzungen, wie PT1 bezeichnet.
P bezeichnet dabei einen Verstärker,
T einen Tiefpass und
I ein Integrierglied (auch eine Art Tiefpass, aber ohne Eckfrequenz)
D ist ein Differenzierglied
Die Zahl (hier 1) bezeichnet die Ordnung

PT1-Element


Das PT1-Element ist ein Tiefpass 1. Ordnung. Die Übertragungsfunktion lautet:
fed-Code einblenden
Bild Bild
gnuplot
reset
set term aqua
 
F(jw)=20*log10(abs(K/(1+jw*{0,1}*T)))
K = 2
T = 0.001
set dummy jw
 
# Typen von Hilfslinien
set style line 3 lt 3 lw 1
set style arrow 3 nohead lt 3 lw 1
set style line 4 lt 3 lw 1
set style arrow 4 nohead lt 3 lw 1
 
# Hilfslinien zeichnen
set arrow 1 from 100,6 to 1000,6 as 3
set arrow 2 from 1000,6 to 100000,-34 as 3
set arrow 3 from 2000,0 to 20000,0 as 4
set arrow 4 from 20000,0 to 20000,-20 as 4
 
# Achsen und Einteilungen
set mxtics 10
set grid xtics mxtics
set grid ytics mytics
set xrange [100 : 100000.0]
set yrange [-40:10.0]
set logscale x
set ytics (10,6,3,0,-10,-20,-30,-40)
set tics out
 
# Beschriftungen
set nokey
set label 3 "Eckfrequenz" at 1000,7 l font "Helvetica,15"
set label 4 "Steigung -20dB/Dekade" at 3500,-2 l font "Helvetica,15"
set title "Bode Diagramm des PT1 Elements" font "Helvetica,30"
set ylabel "|F(jw)| in dB" font "Helvetica,20"
set xlabel "Kreisfrequenz w" font "Helvetica,20"
 
plot F(jw)
Schön wären gestrichelte Linien. Diese gibt es jedoch nicht auf jedem Terminal zu haben. Ich werde später noch ein Beispiel mit Postscript zeigen.

PT2-Element


Das PT2-Element hat folgende Übertragungsfunktion:
fed-Code einblenden
Man sieht der Formel für die Resonanzfrequenz schnell an, dass der Wurzelausdruck auch imaginär werden kann.
fed-Code einblenden
Bild

Bei diesem Beispiel habe ich Phasen- und Amplitudengang in einem Diagramm zusammengefasst. Dazu muss gnuplot in den Multiplot-Modus gesetzt werden. Dieser muss wieder zurückgesetzt werden, um in den gnuplot-Standardmodus zurück zu gelangen. Befehle, wie das Setzen des terminals funktionieren nur im Standardmodus.
Der gnuplot Code dazu sieht folgendermassen aus:
gnuplot
reset
unset multiplot
set samples 2001
set terminal aqua
 
G(w)=K*w0**2/((w*{0,1})**2+2*D*w0*{0,1}*w+w0**2)
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
 
K = 1
D = 0.2
w0 = 1000
 
# Typen von Hilfslinien
set style line 3 lt 3 lw 1
set style arrow 3 lt 3 lw 1
set style line 4 lt 3 lw 1
set style arrow 4 nohead lt 3 lw 1
 
set multiplot
 
# Amplitude
set size 1,0.5
set origin 0,0.5
 
# Achsen und Einteilungen
set mxtics 10
set grid xtics mxtics
set grid ytics mytics
set xrange [100 : 10000.0]
set yrange [-40:10.0]
set logscale x
set ytics (10,0,-10,-20,-30,-40)
set tics out
 
# Beschriftungen
set nokey
set label 2 "Resonanz bei 959Hz" at 450,-5 l font "Helvetica,15"
set label 3 "Überhöhung 8.1dB" at 1300,6 l font "Helvetica,15"
set label 4 "Steigung -40dB/Dekade" at 1000,-20 l font "Helvetica,15"
set xlabel "jw"
set ylabel "|G(jw)| in dB" font "Helvetica,15"
set xlabel "Kreisfrequenz w" font "Helvetica,15"
set title "PT2 Element: Amplitudengang"  font "Helvetica,20"
 
#Asymtoten
set arrow 1 from 100,0 to 1000,0 as 4
set arrow 2 from 1000,0 to 10000,-40 as 4
set arrow 3 from 959,0 to 959,8.1 as 3
set arrow 4 from 959,8.1 to 1250,8.1 as 4
 
#Amplitudengang
plot dB(x)
 
reset
# Phase
set size 1,0.5
set origin 0,0
 
# Achsen und Einteilungen
set mxtics 10
set grid xtics mxtics
set grid ytics mytics
set xrange [100 : 10000.0]
set yrange [-180 : 0.0]
set logscale x
 
# Beschriftungen
set nokey
set xlabel "jw"
set ylabel "Phase in Grad" font "Helvetica,15"
set xlabel "Kreisfrequenz w" font "Helvetica,15"
set title  "PT2 Element Phasengang"  font "Helvetica,20"
plot P(x)
unset multiplot

DT1-Element


Bei differenzierenden Gliedern steigt die Amplitude mit der Frequenz an.
Das DT1-Glied hat die folgende Übertragungsfunktion:
fed-Code einblenden
Bild
Die Funktion wurde mit gnuplot folgendermassen erzeugt:
gnuplot
G(w)=K*w*{0,1}/(1+T1*w*{0,1})
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
K = 0.01
T1 = 0.001

Multiplikativer PID-Regler


In diesem Abschnitt wurde folgende Übertragungsfunktion verwendet:
fed-Code einblenden
Bild
gnuplot
G(w)=K*(1+TN*w*{0,1})*(1+TV*w*{0,1})/(TN*w*{0,1})
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
 
K = 1
TN = 0.01
TV = 0.001

Additiver PIDT1-Regler


Der Vollständigkeit halber wurde hier noch ein T1-Glied (Tiefpass) ergänzt. Braucht man ihn nicht, so setzt man T1=0.
fed-Code einblenden
Bild
Dieses Diagramm kann man nicht mehr direkt aus der Übertragungsfunktion ableiten. Die additive Form ist für die Konstruktion von Reglern zwar vorteilhaft, der Frequenzgang kann aber erst nach einigen Umrechnungen abgeschätzt werden.
Um die additive in die multiplikative Form umzuwandeln, muss man Darstellungen mit gleichen Null- und Polstellen und gleichem konstanten Faktor finden.
Für die Multiplikative Form wurde der Index m und für die additive Form der Index a verwendet. Unten steht das Resultat der Umrechnung:

fed-Code einblenden

Bei diesem Diagramm habe ich die postscript Ausgabe verwendet. Damit sind sowohl gestrichelte Linien, als auch griechische Buchstaben darstellbar. In den Codeabschnitten unten ist die Verwendung der Funktion und der griechischen Buchstaben gezeigt. Auf anderen Terminals werden die Symbol-Sequenzen einfach wie im Quelltext angezeigt.  
gnuplot
set terminal postscript enhanced landscape color lw 2 "Times-Roman" 20
set output "PID_A.ps"
 
G(w)=K*(1+1/(TN*w*{0,1})+TV*w*{0,1}/(1+T1*w*{0,1}))
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
 
K = 2
TN = 0.01
TV = 0.002
T1 = 0.001
 
set label 1 "{/Symbol w}_2" at 145,-4 l
 
All logos and trademarks in this site are property of their respective owner. The comments are property of their posters, all the rest © 2001-2017 by Matroids Matheplanet
This web site was made with PHP-Nuke, a web portal system written in PHP. PHP-Nuke is Free Software released under the GNU/GPL license.
Ich distanziere mich von rechtswidrigen oder anstößigen Inhalten, die sich trotz aufmerksamer Prüfung hinter hier verwendeten Links verbergen mögen.
Lesen Sie die Nutzungsbedingungen, die Distanzierung, die Datenschutzerklärung und das Impressum.
[Seitenanfang]