Die Mathe-Redaktion - 28.02.2020 14:29 - Registrieren/Login
Auswahl
ListenpunktHome
ListenpunktAktuell und Interessant ai
ListenpunktArtikelübersicht/-suche
ListenpunktAlle Links / Mathe-Links
ListenpunktFach- & Sachbücher
ListenpunktMitglieder / Karte / Top 15
ListenpunktRegistrieren/Login
ListenpunktArbeitsgruppen
Listenpunkt? im neuen Schwätz
ListenpunktWerde Mathe-Millionär!
ListenpunktFormeleditor fedgeo
Schwarzes Brett
Aktion im Forum
Suche
Stichwortsuche in Artikeln und Links von Matheplanet
Suchen im Forum
Suchtipps

Bücher
Englische Bücher
Software
Suchbegriffe:
Mathematik bei amazon
Naturwissenschaft & Technik
In Partnerschaft mit Amazon.de
Kontakt
Mail an Matroid
[Keine Übungsaufgaben!]
Impressum

Bitte beachten Sie unsere Nutzungsbedingungen, die Distanzierung, unsere Datenschutzerklärung und
die Forumregeln.

Sie können Mitglied werden. Mitglieder können den Matheplanet-Newsletter bestellen, der etwa alle 2 Monate erscheint.

Der Newsletter Okt. 2017

Für Mitglieder
Mathematisch für Anfänger
Wer ist Online
Aktuell sind 752 Gäste und 15 Mitglieder online.

Sie können Mitglied werden:
Klick hier.

Über Matheplanet
 
Zum letzten Themenfilter: Themenfilter:
Matroids Matheplanet Forum Index
Moderiert von Curufin epsilonkugel
Analysis » Folgen und Reihen » Beweis einer Summenformel
Druckversion
Druckversion
Antworten
Antworten
Autor
Universität/Hochschule Beweis einer Summenformel
said9090
Junior Letzter Besuch: vor mehr als 3 Monaten
Dabei seit: 23.10.2015
Mitteilungen: 5
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Themenstart: 2015-10-25


Abend,

Wir haben in der Vorlesung folgende Aufgabe durchgenommen
fed-Code einblenden


Ich weiß, dank der Vorgabe unseres Professors, dass man wie in Wikibooks vorgehen kann. Ich würde gern wissen ob es noch einfachere Möglichkeiten gibt die Aufgabe zu lösen, (außer der Vollständigen Induktion) denn ich wäre nie im Leben selbständig auf die Lösung von Wikibooks gekommen.
de.wikibooks.org/wiki/Mathe_f%C3%BCr_Nicht-Freaks:_Geometrische_Summenformel

VG Said



  Profil  Quote  Link auf diesen Beitrag Link
Wauzi
Senior Letzter Besuch: im letzten Monat
Dabei seit: 03.06.2004
Mitteilungen: 11372
Aus: Bayern
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.1, eingetragen 2015-10-25


fed-Code einblenden


-----------------
Primzahlen sind auch nur Zahlen



  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.2, eingetragen 2015-10-26


Hallo.

"Ich würde gern wissen ob es noch einfachere Möglichkeiten gibt die Aufgabe zu lösen, (außer der Vollständigen Induktion)"

Natürlich kann man das Ganze auch ohne Induktion beweisen.

Siehe:
mathematica
(* In *)
Clear @geosum
geosum[n_, x_] := Sum[x^k, {k, 0, n}]
geosum[n, x]
 
(* Out *)
 
(-1 + x^(1 + n))/(-1 + x)
 

Dieser Beweis benutzt mit Sicherheit keine "vollständige Induktion".

Es muss also zwingend auch ohne Induktion funktionieren.

Ein CAS benutzt hierfür die  Teleskopsumme.

Diese kannst Du natürlich auch benutzen.

Erweitere <math>x^k</math> mit <math>(1-x)</math>.

Dann ergibt sich <math>\displaystyle x^k=\frac {x^k-x^{k+1}}{1-x}</math> und das Ergebnis steht mit der Teleskopsumme da.

Gruß endy





-----------------
Dean Koontz : Zwielicht

Unzählige verschlungene Nachtpfade zweigen vom Zwielicht ab.
Etwas bewegt sich inmitten der Nacht,das nicht gut und nicht richtig ist.

The Book of Counted Sorrows.




  Profil  Quote  Link auf diesen Beitrag Link
Folgende Antworten hat der Fragesteller vermutlich noch nicht gesehen.
Wally
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 02.11.2004
Mitteilungen: 8662
Aus: Dortmund, Old Europe
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.3, eingetragen 2015-10-26


Eine sehr seltsame Argumentation, endy.

Es kann sein, dass in Mathematica geometrische Summen hart verdrahted sind und nicht auf Teleskopsummen zurückgeführt werden.

Wally



  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.4, eingetragen 2015-10-27


Hallo.

2015-10-26 22:30 - Wally in Beitrag No. 3 schreibt:
Eine sehr seltsame Argumentation, endy.

Was ist denn daran seltsam?


Es kann sein, dass in Mathematica geometrische Summen hart verdrahted sind und nicht auf Teleskopsummen zurückgeführt werden.

Wally

Mit Sicherheit kann dies nicht sein.Die geometrische Summe ist in mathematica nicht "hart verdrahted" und mathematica kennt sie nicht.

Bringen wir einfach mit geosumbad mma die geometrische Summenformel bei.

Man schaue sich z.B. folgenden Code an:
mathematica
ClearAll @ "Global`*"
Clear @geosum
geosum[n_, x_] := Sum[x^k, {k, 0, n}]
Clear @geosumbad
geosumbad[n_, x_] := (1 - x^(n + 1))/(1 - x)
 
geosum[n, x]
geosumbad[n, x]
geosum[n, x] == geosumbad[n, x] // Simplify
lsta := Table[geosum[n, x], {j, 1, 10}]
lstb := Table[geosumbad[n, x], {j, 1, 10}]
lsta
lstb
lstlargea := Table[geosum[n, x], {j, 1, 10^5}]
lstlargeb := Table[geosumbad[n, x], {j, 1, 10^5}]
lstlargea; // AbsoluteTiming // First
lstlargeb; // AbsoluteTiming // First

Um lstlargea zu berechnen braucht mma bei mir mehr als 10mal so lang wie um lstlargeb zu berechnen,etwa 14.75 Sekunden zu 1.44 Sekunden.

Dies liegt einfach daran ,dass mma sich 100000 die geometrische Summenformel herleiten muss und dies tut das System mit einer Teleskopsumme.

Genauer mit einem Algorithmus den  Bill Gosper 1977 gefunden hat:  Gosper's algorithm

Man siehe auch  hier.

Gruß endy

Nachricht zur Änderung: Weiteren Link eingefügt.


-----------------
Dean Koontz : Zwielicht

Unzählige verschlungene Nachtpfade zweigen vom Zwielicht ab.
Etwas bewegt sich inmitten der Nacht,das nicht gut und nicht richtig ist.

The Book of Counted Sorrows.




  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.5, eingetragen 2016-03-30


Hallo.

Da hier die Frage aufgekommen ist wie mathematica bzw. ein modernes CAS die geometrische Summenformel berechnet.

Hier ist die genaue Antwort:
mathematica
(* In *)
 
Clear @ gosper
 
gosper :: usage = 
  "gosper[term,{var,n0,n1}] finds the values of Sum[term,{var,n0,n1}] 
for symbolic n0 and n1.";
 
(* linearity *)
gosper[an_ + bn_, {var_, n0_, n1_, inc_}] := 
 gosper[an, {var, n0, n1, inc}] + gosper[bn, {var, n0, n1, inc}]
 
(* default increment *)
gosper[an_, {var_, n0_, n1_}] := gosper[an, {var, n0, n1, 1}]
 
(* default startvalue *) 
gosper[an_, {var_, n1_}] := gosper[an, {var, 1, n1, 1}]
 
(* trivial cases *)
gosper[an_, {var_, n0_, n1_, 1}] := an (n1 - n0 + 1) /; FreeQ[an, var]
gosper[an_, {var_, n0_, n0_, _}] := an /. var -> n0
 
Subvar[expr_, old_Symbol, new_] := expr /. old -> new
 
gosper[an_, {var_, n0_, n1_, 1}] := Block[
  {pn, qn, rn, an1, rnj, jj, res, resn, resp, rat, ann, qrpos, ii, 
   qrneg, dqrpos, dqrneg, dk, dp, fn, sn, k0, eq, i, s0, s1},
  ann = an;
  an1 = Subvar[ann, var, var - 1];
  rat = ann/an1; (* user defined rules take effect here *)
  rat = Together[rat];
  qn = Numerator[rat];
  rn = Denominator[rat];
  If[! PolynomialQ[qn, var] || ! PolynomialQ[rn, var], (* 
   not a rational function *)
   Return[Sum[an, {var, n0, n1, 1}]]];
  pn = 1;
  rnj = Expand[Subvar[rn, var, var + jj]];
  res = Resultant[qn, rnj, var];
  res = FactorList[res];
  res = Map[#[[1]] &, res];
  (* find factors linear in jj *)
  resp = Cases[res, jj + _Integer];
  resn = Cases[res, -jj + n_Integer];
  res = Join[-(resp - jj), resn + jj];
  res = Select[res, Positive];
  (* adjust for positive integer zeros *)
  For[resn = Length[res], resn > 0, resn--,
   Block[{gn, gnj},
    gn = GCD[qn, Expand[Subvar[rn, var, var + res[[resn]]]], var];
    qn = Cancel[qn/gn];
    gnj = gn;
    For[i = 1, i <= res[[resn]], i++,
      pn = Expand[pn gnj];
        gnj = Expand[Subvar[gn, var, var - i]]
     ];
    rn = Cancel[rn/gnj]]
   ];
  (* find degree bound *)
  qn = Expand[Subvar[qn, var, var + 1]];
  dp = Exponent[pn, var];
  qrpos = Expand[qn + rn]; dqrpos = Exponent[qrpos, var];
  qrneg = Expand[qn - rn]; dqrneg = Exponent[qrneg, var];
  If[dqrpos <= dqrneg, dk = dp - dqrneg,
   If[dqrneg < dqrpos - 1 || dqrneg == -1, dk = dp - dqrpos + 1,
    (* else *)
    k0 = -Cancel[Coefficient[qrneg, var^dqrneg]/
        Coefficient[qrpos, var^dqrpos]];
    dk = If[IntegerQ[k0], Max[k0, dp - dqrpos + 1],
      dp - dqrpos + 1]
    ]
   ];
  If[dk >= 0,(* solution possible *)
   fn = Sum[f[ii] var^ii, {ii, 0, dk}];
   eq = Expand[pn - qn fn + rn Subvar[fn, var, var - 1]];
   eq = CoefficientList[eq, var];
   eq = Solve[Thread[eq == 0], Array[f, dk + 1, 0]];
   If[Length[eq] > 0,
    fn = fn /. eq[[1]];
    fn = fn /. f[0] -> 0; (* summation constant *)
    sn = Cancel[qn/pn*fn] ann;
    (* crude test for infinity *)
    s1 = sn /. var -> n1;
    s0 = (sn /. var -> n0) - ( ann /. var -> n0 );
    Return[s1 - s0],
    (* else fail *)
    Return[Sum[an, {var, n0, n1, 1}]]
      ],
   (* else fail *)
   Return[Sum[an, {var, n0, n1, 1}]]
   ]]
 
? gosper
 

Dies ist eine Menge Algebra,um sich die geometrische Summenformel herzuleiten.

Ich habe diese Implementierung von Gosper in mma in dem Mathematica Buch von Wolfram zur Version 1.2 aus dem Jahr 1988 gefunden.
mathematica
(* In *)
 
sol = gosper[q^j, {j, 0, n}]
Simplify @sol
 
(* Out *)
 
1 - q/(-1 + q) + q^(1 + n)/(-1 + q)
(-1 + q^(1 + n))/(-1 + q)
 

Aber mit gosper kann man natürlich noch deutlich mehr berechnen:
mathematica
(* In *)
gosper[j, {j, 1, n}]
gosper[j^2, {j, 1, n}]
gosper[Sum[c[j]*k^j, {j, 0, 10}], {k, 1, n}] == 
  Sum[Sum[c[j]*k^j, {j, 0, 10}], {k, 1, n}] // Simplify
gosper[k*k!, {k, 1, n}]
gosper[1/((k)*(k + 1)*(k + 2)), {k, 1, Infinity}]
gosper[1/k*1/(k + 4), {k, 1, n}]
 
(* Out *)
 
1/2 n (1 + n)
1/6 n (1 + n) (1 + 2 n)
True
-1 + (1 + n)!
1/4
25/48 + 1/4 (-(1/(1 + n)) - 1/(2 + n) - 1/(3 + n) - 1/(4 + n))

Gruß endy



  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.6, eingetragen 2018-11-22


Achtung : Wer dies liest kann vielleicht den Spass daran verlieren Summen auszurechnen.



Da hier in dem Thread und in dem Thread zu Link1 (verlinke ich später ) von Induktion gesprochen wurde,erstmal

Vollständige Indoktrination

Manchmal hat man so Momente da fragt man sich wie konnte man so etwas übersehen.

Also mma ist cleverer als man denkt.

In Beitrag Nr.2 habe ich behauptet,dass mma die geometrische Summe mittels einer Teleskopsumme ausrechnet und in Beitrag Nr.5 findet man den Algorithmus dazu.

Man schaue Link 1.

Moderne Versionen von Gosper,die man in mma als Package laden kann,geben einem auch die diskrete Stammfunktion p direkt an.

Dies ist wirklich das einzig schwierige um eine Summe als Teleskopsumme auszurechnen der Übergang von q nach p.

Durch einen anderen Thread bin ich jetzt auf die Idee gekommen dies auch direkt einmal bei Sum auszuprobieren:
mathematica
(* In *)
 
q[x_, k_] := x^k
diq[x_, k_] := Sum[q[x, k], k]
q[x, k]
diq[x, k]
 
(* Out *)
 
x^k
x^k/(-1 + x)
 

Mathematicas Sum liefert einem also direkt diskrete Stammfunktionen.Funktioniert in mma7 und mma10.

Diese werden natürlich mit Gosper berechnet.Aber man braucht keine modere Version von Gosper in mma zu laden ,um sich die Stammfunktion anzeigen zu lassen.

Man sieht bei diesem Beispiel sofort,dass mma richtig gerechnet hat.Man kann es aber auch nachrechnen lassen:

Link 2.


mathematica
(* In *)
Clear @ "Global`*"
 
Clear @ discreteIntegrateQ
discreteIntegrateQ ::usage = 
  "discreteIntegrateQ[{f[k],g[k]},k] ist eine Predicatefunktion,die \
testet ,ob g[k] die diskrete Stammfunktion von f[k] ist,also ob gilt \
: f[k]=g[k+1]-g[k].";
discreteIntegrateQ[{lhs_, rhs_}, var_Symbol] := 
 With[{test = (lhs == ( rhs /. var -> var + 1) - rhs // Simplify) // 
     FullSimplify},
  If[test === True, True, False]
  ]
? discreteIntegrateQ 
 
q[x_, k_] := x^k
diq[x_, k_] := Sum[q[x, k], k]
q[x, k]
diq[x, k]
discreteIntegrateQ[{q[x, k], diq[x, k]}, k]
 
(* Out *)
 
...
x^k
x^k/(-1 + x)
True
 


oder natürlich per Hand nachrechnen falls erwünscht.

Die Aufgabe in dem Link1 löst man dann folgendermaßen
mathematica
(* In *)
 
h[k_] := 1/(k (k + 1)*(k + 2))
dih[k_] := Sum[h[k], k]
h[k]
dih[k]
discreteIntegrateQ[{h[k], dih[k]}, k]
 
(* Out *)
 
1/(k (1 + k) (2 + k))
1/(2 k (1 + k))
True
 

oder man rechnet es per Hand nach.

Das Gleiche Verfahren funktioniert immer,falls eine diskrete Stammfunktion existiert.

Davon gibt es wirklich viele auf dem Planeten und auch sehr schwierige.

Viel Spass beim Teleskopsummen berechnen wünscht euch



endy



  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.7, eingetragen 2018-11-25




Ich habe jetzt einmal MMa für Teleskopsummen etwas getunt.
mathematica
Clear @ "Global`*"
 
discreteIntegrate :: usage = 
  "discreteIntegrate[f[k],k] berechnet zu f[k] die diskrete \
Stammfunktion g[k]. Es gilt also f[k]= g]k+1}-g[k].";
 
discreteIntegrate[fun_, var_Symbol] := Sum[fun, var]
 
discreteIntegrateQ ::usage = 
  "discreteIntegrateQ[{f[k],g[k]},k] ist eine Predicatefunktion,die \
testet ,ob g[k] die diskrete Stammfunktion von f[k] ist,also ob gilt \
: f[k]=g[k+1]-g[k].";
 
discreteIntegrateQ[{lhs_, rhs_}, var_Symbol] := 
 With[{test = (lhs == ( rhs /. var -> var + 1) - rhs // Simplify) // 
     FullSimplify},
  If[test === True, True, False]
  ]
 
telescopSum :: usage = 
  "Es gilt telescopSum[f[k],{k,a,b}]=Sum[f[k],{k,a,b}]=g[b+1]-g[a] \
wobei f[k}=g[k+1]-g[k] ist.g ist also die diskrete Stammfunktion zu f \
und telescopSum kann nur Teleskopsummen berechnen.Mittels des \
Optionvalue Certificate->True wird g als Zertifikat angezeigt.Die \
Ausgabe von telescopSum wird immer auf das Zertifikat von Mma \
getestet.";
 
Options[telescopSum] = {Certificate -> False};
telescopSum[fun_, {var_, begin_, end_}, opts___?OptionQ] := 
 Block[{g, solutiondiscreteIntegrateQ, telescopsum, solution},
 
  (* Berechnen der diskreten Stammfunktion mittels Gosper für \
hypergeometrische fun in var und Memerisation von dieser *)
  mem : g[var1_] := mem = discreteIntegrate[fun, var1] // Simplify;
 
  (* Test, ob die von Gosper für hypergeometrische fun in var bzw. 
  Mathematicas Sum bestimmte diskrete Stammfunktion wirklich stimmt *)
 
 
  solutiondiscreteIntegrateQ = discreteIntegrateQ[{fun, g[var]}, var];
 
  (* Ausgabe telescopSum falls Certificate \[Rule] False *)
  telescopsum = ((g[var] /. ( var -> end + 1)) - (g[var] /. 
        var -> begin)) // Simplify;
 
  (* Der Option Certificate wird ein Wert zugewiesen und solution die \
Werte zugeteilt einmal mit Zertifikat und einmal ohne *)
  If[Certificate /. Flatten[{opts}] /. Options @telescopSum, 
   solution = {telescopsum, g[var]}, solution = telescopsum];
 
  (* Ergebnis von telescopSum ausgeben,
  falls solutiondiscreteIntegrateQ True ,
  ansonsten den Ausdruck unausgewertet zurückgeben *)
  If[solutiondiscreteIntegrateQ, solution, 
   "telescopSum"[fun, {var, begin, end}]]
 
  (* Ende von telescopSum *)
  ]
 
? discreteIntegrate
? discreteIntegrateQ
? telescopSum
 
telescopSum[q^j, {j, 0, n}]
telescopSum[q^j, {j, 0, n}, Certificate -> True]
 


1 ) telescopSum[(2 k - 1)^3, {k, 1, n}]


2 ) telescopSum[1/(a + k - 1)*1/(a + k), {k, 1, n}]


3 ) telescopSum[1/k*1/(k + 1)*1/(k + 2), {k, 1, n}]


4 ) telescopSum[1/((3 k + 1) (3 k + 4) (3 k + 7)), {k, 1, n}]


5 ) telescopSum[k/2^k, {k, 1, n}]


6 ) telescopSum[n^k (n - k)/k!, {k, 0, n - 1}]


7 ) telescopSum[(z + k)!/z!, {z, 0, k - 1}]

8 ) telescopSum[(1 - (k/n)^2)/n, {k, 0, n}]


endy





  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.8, eingetragen 2018-12-13


Noch einmal
mathematica
(* In *)
 
Options @ Sum
 
(* Out *)
 
{Assumptions :> $Assumptions, GenerateConditions -> False, 
 Method -> Automatic, Regularization -> None, 
 VerifyConvergence -> True}
 

In der Dokumentation unter Sum und dann Details and Options steht folgendes:

Die Option Method kann 22 Werte annehmen:

"Automatic" welches der von MMA gewählte Standardwert ist und
{"HypergeometricTermFinite", "HypergeometricTermGosper",
  "HypergeometricTermPFQ", "HypergeometricTermZeilberger",
  "LevelCounting", "Logarithmic", "PeriodicFunction",
  "PolyGammaHypergeometricSeries", "PolyGammaIntegralRepresentation",
  "PolyGammaSumByParts", "Polynomial", "PolynomialExponential",
  "PolynomialTrigonometric", "Procedural",
  "QHypergeometricTermGosper", "QHypergeometricTermZeilberger",
  "QRationalFunction", "RationalExponential", "RationalFunction",
  "RationalTrigonometric", "TableLookup"};

Zu "TableLookup" steht folgendes in der Doko:

summation based on table lookup

Berechnen wir jetzt einmal die geometrische Summenfornel mit MMA und "TableLookup"
mathematica
(* In *)
 
Sum[q^j, {j, 0, n}, Method -> "TableLookup"]
 
(* Out *)
 
Sum[q^j, {j, 0, n}, Method -> "TableLookup"]
 

Hier ist noch eine Funktion sumMethods
mathematica
Clear @ "Global`*"
 
sumMethods :: usage = 
  "sumMethods[fun,{var,begin,end}] berechnet Sum[fun,{var,begin,end}] \
mit allen 21 in MMA 10 zur Verfügung stehenden Methoden und gibt die \
erfolgreichen Berechnungen an mitsamt den dazugehörigen Methoden.";
 
sumMethods[fun_, {var_, begin_, end_}] :=
 Block[{methodvalues, solutions, temp, methodfail, methodsucceed},
 
  (* Liste der Methodwerte die die Option Method der Summenfunktion \
Sum in MMA 10 annehmen kann ausser "Automatic" *) 
  methodvalues = {"HypergeometricTermFinite", 
    "HypergeometricTermGosper", "HypergeometricTermPFQ", 
    "HypergeometricTermZeilberger", "LevelCounting", "Logarithmic", 
    "PeriodicFunction",
    "PolyGammaHypergeometricSeries", 
    "PolyGammaIntegralRepresentation", "PolyGammaSumByParts", 
    "Polynomial", "PolynomialExponential", "PolynomialTrigonometric", 
    "Procedural", "QHypergeometricTermGosper", 
    "QHypergeometricTermZeilberger", "QRationalFunction", 
    "RationalExponential", "RationalFunction", 
    "RationalTrigonometric", "TableLookup"};
 
  (* Anwenden aller methodvalues mit der Option Method auf die \
gewünschte Summe *)
  solutions = 
   Sum[fun, {var, begin, end}, Method -> #] & /@ methodvalues;
 
  (* Bestimmen der methodvalues die nicht funktioniert haben *)
  methodfail = 
   Cases[solutions, 
    temp[___, Method -> value_ ] :> value /. temp -> Sum];
 
  (* Bestimmen der methodvalues die funktioniert haben *)
  methodsucceed = Complement[methodvalues, methodfail];
 
  (* Ausgabe der Summenergebnisse wo die Methoden funktiniert haben \
mitsamt den jeweiligen methodvalues *)
  {Sum[fun, {var, begin, end}, Method -> #] & /@ methodsucceed, 
    Method -> methodsucceed // Thread } // Transpose
 
  (*Ende von sumMethods *)
  ]
 
? sumMethods
 

Eine Anwendung
mathematica
(* In *)
 
sumMethods[q^j, {j, 0, n}]
 
(* Out *)
 
{{(-1 + q^(1 + n))/(-1 + q), 
  Method -> "HypergeometricTermFinite"}, {(-1 + q^(1 + n))/(-1 + q), 
  Method -> "HypergeometricTermPFQ"}, {(-1 + q^(1 + n))/(-1 + q), 
  Method -> "PolynomialExponential"}, {(-1 + q^(1 + n))/(-1 + q), 
  Method -> "QRationalFunction"}, {(-1 + q^(1 + n))/(-1 + q), 
  Method -> "RationalExponential"}}
 

endy



  Profil  Quote  Link auf diesen Beitrag Link
endy
Senior Letzter Besuch: in der letzten Woche
Dabei seit: 10.01.2011
Mitteilungen: 3200
Zum letzten BeitragZum nächsten BeitragZum vorigen BeitragZum erstem Beitrag  Beitrag No.9, eingetragen 2019-06-28


Eine weitere Anwendung von telescopSum , man siehe Klick mich:
mathematica
(* In *)
 
f[k_] := (k + 7)/((k + 1)*(k + 3)*(k + 4))
Sum[f[k], {k, 0, Infinity}]
sol1 = telescopSum[f[k], {k, 0, n}] // Apart
sol2 = sol1 /. n -> Infinity
sol3 = telescopSum[f[k], {k, 0, n}, Certificate -> True] // Apart
 
(* Out *)
 
7/6
7/6 - 1/(2 + n) - 1/(3 + n) + 1/(4 + n)
7/6
{7/6 - 1/(2 + n) - 1/(3 + n) + 1/(4 + n), -(1/(1 + k)) - 1/(2 + k) + 
  1/(3 + k)}
 

endy



  Profil  Quote  Link auf diesen Beitrag Link
Neues Thema [Neues Thema] Antworten [Antworten]    Druckversion [Druckversion]

 


Wechsel in ein anderes Forum:
 Suchen    
 
All logos and trademarks in this site are property of their respective owner. The comments are property of their posters, all the rest © 2001-2019 by Matroids Matheplanet
This web site was made with PHP-Nuke, a web portal system written in PHP. PHP-Nuke is Free Software released under the GNU/GPL license.
Ich distanziere mich von rechtswidrigen oder anstößigen Inhalten, die sich trotz aufmerksamer Prüfung hinter hier verwendeten Links verbergen mögen.
Lesen Sie die Nutzungsbedingungen, die Distanzierung, die Datenschutzerklärung und das Impressum.
[Seitenanfang]